Local Library and renumbering parts

I seemed to have lost my local library on my desktop.

I still have it on my laptop but it runs much slower as it is an older one.

In addition to this I cannot renumber the parts as I have added some additional LEDs.

Any Suggestions.
project
project
Middle-Center Section.project
21K
·

Comments

  • Recycle bin?
    The developer of AutoTRAX DEX. 
    ·
  • I'm always careful with my own created library. A fresh installationm or update of DEX should not delete them but I take no chances and have backup of all.
    Default library place is in users....roaming.... but you can direct DEX to look elsewhere.
    ·
  • The installer does not delete any library files.
    The developer of AutoTRAX DEX. 
    ·
  • And what about an uninstall?
    ·
  • This is  the installer script. (Innosetup)
    #include <idp.iss>
    #include "..\_vendor\Inno Setup\scripts\products.iss"
    #include "..\_vendor\Inno Setup\scripts\products\winversion.iss"
    #include "..\_vendor\Inno Setup\scripts\products\fileversion.iss"


    [Languages]
    Name: "en"; MessagesFile: "compiler:Default.isl"
    Name: "nl"; MessagesFile: "compiler:Languages\Dutch.isl"
    Name: "fr"; MessagesFile: "compiler:Languages\French.isl"
    Name: "de"; MessagesFile: "compiler:Languages\German.isl"
    Name: "pt"; MessagesFile: "compiler:Languages\Portuguese.isl"
    Name: "es"; MessagesFile: "compiler:Languages\Spanish.isl"
    Name: "pl"; MessagesFile: "compiler:Languages\Polish.isl"
    Name: "da"; MessagesFile: "compiler:Languages\danish.isl"
    Name: "it"; MessagesFile: "compiler:Languages\italian.isl"
    Name: "cz"; MessagesFile: "compiler:Languages\Czech.isl"
    Name: "ru"; MessagesFile: "compiler:Languages\russian.isl"
    Name: "hu"; MessagesFile: "compiler:Languages\hungarian.isl"
    Name: "no"; MessagesFile: "compiler:Languages\norwegian.isl"
    Name: "br"; MessagesFile: "compiler:Languages\BrazilianPortuguese.isl"
    Name: "sl"; MessagesFile: "compiler:Languages\slovenian.isl"
    Name: "sl"; MessagesFile: "compiler:Languages\finnish.isl"
    Name: "he"; MessagesFile: "compiler:Languages\hebrew.isl"

    [InstallDelete]
    Type: files; Name: "{app}\*.pdb";
    Type: files; Name: "{app}\Dapper.dll";
    Type: files; Name: "{app}\System.Data.SQLite.dll";
    Type: files; Name: "{app}\x64\SQLite.Interop.dll";
    Type: files; Name: "{app}\x86\SQLite.Interop.dll";
    Type: files; Name: "{app}\Active3D.exe";
    Type: files; Name: "{app}\AutoTRAX.exe";
    Type: files; Name: "{app}\Sketcher.exe";
    Type: files; Name: "{app}\PartBuilder.exe";
    Type: files; Name: "{app}\Antlr3.Runtime.dll";
    Type: files; Name: "{app}\Antlr4.Runtime.net40.dll";
    Type: files; Name: "{app}\Antlr4.Runtime.Standard.dll";
    Type: files; Name: "{app}\LogitechLcd.x64.dll";
    Type: files; Name: "{app}\LogitechLcd.x86.dll";
    Type: files; Name: "{app}\SolidModeller.dll";
    Type: files; Name: "{app}\OpenTK.dll";
    Type: files; Name: "{app}\OpenTK.GLControl.dll";
    Type: files; Name: "{app}\OpenGL.dll";
    Type: files; Name: "{app}\OpenGLControl.dll";
    Type: files; Name: "{app}\sgCore64.dll";
    Type: files; Name: "{app}\Geometry.dll";
    Type: files; Name: "{app}\Gerber.dll";
    Type: files; Name: "{app}\GerberReader.dll";
    Type: files; Name: "{app}\Graphs.dll";
    Type: files; Name: "{app}\CodeEditor.dll";
    Type: files; Name: "{app}\MainWindow.dll";
    Type: files; Name: "{app}\MainWindow2D.dll";
    Type: files; Name: "{app}\Media3D.dll";
    Type: files; Name: "{app}\Panels.dll";
    Type: files; Name: "{app}\Printing.dll";
    Type: files; Name: "{app}\Engine.dll";
    Type: files; Name: "{app}\SimulatorData.dll";
    Type: files; Name: "{app}\Simulator.exe";
    Type: files; Name: "{app}\Spice.dll";
    Type: files; Name: "{app}\XSpice.dll";
    Type: files; Name: "{app}\CircuitSimulator.dll";
    Type: files; Name: "{app}\Spice.exe";
    Type: files; Name: "{app}\DataTypes.dll";
    Type: files; Name: "{app}\DesignControls.dll";
    Type: files; Name: "{app}\DesignEngine.dll";
    Type: files; Name: "{app}\DexDesign.dll";
    Type: files; Name: "{app}\Python.dll";
    Type: files; Name: "{app}\Project.dll";
    Type: files; Name: "{app}\ElectricalUIControls.dll";
    Type: files; Name: "{app}\UIControls.dll";
    Type: files; Name: "{app}\Pcb.dll";
    Type: files; Name: "{app}\PcbRouter.dll";
    Type: files; Name: "{app}\Zip.dll";
    Type: files; Name: "{app}\Support.dll";
    Type: files; Name: "{app}\AutoTRAX.exe.config";
    Type: files; Name: "{app}\AutoTRAX.exe.manifest";
    Type: files; Name: "{app}\AutoTRAX2.exe";
    Type: files; Name: "{app}\AutoTRAX2.exe.config";
    Type: files; Name: "{app}\AutoTRAX2.exe.manifest";
    Type: files; Name: "{app}\pcgw32.dll";
    Type: files; Name: "{app}\DevExpress*.dll";
    Type: files; Name: "{app}\PolygonClipper\msvcr90.dll";
    Type: files; Name: "{app}\PolygonClipper\PolygonClipper32.dll";
    Type: files; Name: "{app}\PolygonClipper\PolygonClipper64.dll";
    Type: files; Name: "{app}\PolygonClipper\Newtonsoft.Json.dll";
    Type: files; Name: "{app}\DemoScripts\*.xml";
    Type: files; Name: "{app}\DemoScripts\*.png";
    Type: files; Name: "{app}\CubeMaps\*.*";
    Type: files; Name: "{app}\Samples\*.*";
    Type: filesandordirs; Name: "{userappdata}\AutoTRAX Software\DEX\Library\___SystemDoNotRemove\Tracks";

    Type: files; Name: "{app}\GerberViewer\gerbv.exe"

    [Setup]
    AppId=AutoTRAXDesignExpress
    LicenseFile=..\..\..\Install\license.txt
    AppPublisher=AutoTRAX Software
    AppPublisherURL=http://www.dexpcb.com/
    ;InfoBeforeFile=\..\..\..\Install\whatsNew.txt
    AppName=AutoTRAX DEX
    AppVerName=AutoTRAX DEX
    AppCopyright=Copyright (C) 2019 AutoTRAX Software
    DefaultDirName={pf}\AutoTRAX Software\DEX
    DefaultGroupName=AutoTRAX Software
    UninstallDisplayIcon={app}\AutoTRAX.exe
    SetupIconFile=..\..\..\AutoTRAX\dx.ico
    Compression=lzma
    SolidCompression=yes
    SourceDir=..\AutoTRAX\bin\Release
    OutputDir=..\..\..
    OutputBaseFilename=_DexSetup
    ArchitecturesAllowed=x86 x64
    WizardImageFile=..\..\..\MainWindow\Images\Install.bmp
    WizardSmallImageFile=..\..\..\MainWindow\Images\InstallSmall.bmp
    ChangesAssociations=yes
    DisableFinishedPage=yes
    UsePreviousSetupType=false

    ArchitecturesInstallIn64BitMode=x64

    [Types]
    Name: "full"; Description: "Full installation"
    Name: "compact"; Description: "Compact installation"
    Name: "custom"; Description: "Custom installation"; Flags: iscustom

    [Tasks]
    Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: checkedonce

    ; File associations
    [Registry]
    Root: HKCR; Subkey: ".project"; ValueType: string; ValueName: ""; ValueData: "Project"; Flags: uninsdeletevalue
    Root: HKCR; Subkey: "Project"; ValueType: string; ValueName: ""; ValueData: "Project"; Flags: uninsdeletekey
    Root: HKCR; Subkey: "Project\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\AutoTRAX.exe,0"
    Root: HKCR; Subkey: "Project\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\AutoTRAX.exe"" ""%1"""

    Root: HKCR; Subkey: ".part"; ValueType: string; ValueName: ""; ValueData: "Part"; Flags: uninsdeletevalue
    Root: HKCR; Subkey: "Part"; ValueType: string; ValueName: ""; ValueData: "Part"; Flags: uninsdeletekey
    Root: HKCR; Subkey: "Part\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\Part.ico,0"
    Root: HKCR; Subkey: "Part\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\AutoTRAX.exe"" ""%1"""

    Root: HKCR; Subkey: ".art"; ValueType: string; ValueName: ""; ValueData: "Art"; Flags: uninsdeletevalue
    Root: HKCR; Subkey: "Art"; ValueType: string; ValueName: ""; ValueData: "Art"; Flags: uninsdeletekey
    Root: HKCR; Subkey: "Art\DefaultIcon"; ValueType: string; ValueName: ""; ValueData: "{app}\art.ico,0"
    Root: HKCR; Subkey: "Art\shell\open\command"; ValueType: string; ValueName: ""; ValueData: """{app}\AutoTRAX.exe"" ""%1"""

    [Files]
    Source: "Antlr4.Runtime.Standard.dll"; DestDir: "{app}"; Flags: ignoreversion

    Source: "IronPython.dll"; DestDir: "{app}"; Flags: ignoreversion

    ; Demo scripts
    Source: "..\..\..\AutoTRAX\DemoScripts\*.xml"; DestDir: "{app}\DemoScripts"; Flags: ignoreversion
    ; Demo images
    Source: "..\..\..\AutoTRAX\DemoScripts\*.png"; DestDir: "{app}\DemoScripts"; Flags: ignoreversion

    ; AutoTRAX
    Source: "..\..\..\AutoTRAX\bin\Release\Simulator.exe"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Spreadsheet.exe"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\TextEditor.exe"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Scheduler.exe"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Active3D.exe"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Sketcher.exe"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\PartCreator.exe"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\Secure\spice.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Secure\DesignEngine.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Secure\Project.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Secure\CodeEditor.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Secure\MainWindow.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\Sketcher\bin\Release\MainWindow2D.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Secure\Panels.dll"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\System.Data.SQLite.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\x64\SQLite.Interop.dll"; DestDir: "{app}\x64"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\x86\SQLite.Interop.dll"; DestDir: "{app}\x86"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\Dapper.dll"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\Secure\*.pdb"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\Secure\DesignEngine.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "OpenGL.dll"; DestDir: "{app}"; Flags: ignoreversion


    Source: "..\..\..\AutoTRAX\bin\Release\Secure\Support.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Secure\ElectricalUIControls.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Secure\UIControls.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Pcb.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Support.XmlSerializers.dll"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\LogitechLcd.x64.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\LogitechLcd.x86.dll"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\Microsoft.Scripting.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Microsoft.Scripting.Metadata.dll"; DestDir: "{app}"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\bin\Release\Microsoft.Dynamic.dll"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\AutoTRAX.exe"; DestDir: "{app}"; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\art.ico"; DestDir: "{app}" ; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\part.ico"; DestDir: "{app}" ; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\dex.png"; DestDir: "{app}" ; Flags: ignoreversion
    Source: "EnglishAlphabet.txt"; DestDir: "{app}"; Flags: ignoreversion
    Source: "english.aff"; DestDir: "{app}"; Flags: ignoreversion
    Source: "american.xlg"; DestDir: "{app}" ; Flags: ignoreversion

    Source: "..\..\..\XSpice\XSpice\visualc\sharedspice\Release.Win32\xspice.dll"; DestDir: "{app}"; Flags: ignoreversion; Check: not IsWin64
    Source: "..\..\..\XSpice\XSpice\visualc\sharedspice\Release.x64\xspice.dll"; DestDir: "{app}"; Flags: ignoreversion; Check: IsWin64

    Source: "ToolTips.txt"; DestDir: "{app}" ; Flags: ignoreversion

    Source: "..\..\..\AutoTRAX\bin\Release\Parts\*.*"; DestDir: "{commonappdata}\AutoTRAX Software\DEX\Parts" ; Flags: recursesubdirs ignoreversion

    Source: "..\..\..\AutoTRAX\PolygonClipper\PolygonClipper32.dll"; DestDir: "{app}\PolygonClipper"; Flags: ignoreversion
    Source: "..\..\..\AutoTRAX\PolygonClipper\PolygonClipper64.dll"; DestDir: "{app}\PolygonClipper" ; Flags: ignoreversion

    Source: "GerberViewer\gerbv.exe"; DestDir: "{app}\GerberViewer"; Flags: ignoreversion


    Source: "DevExpress.*.dll"; DestDir: "{app}" ; Flags: ignoreversion

    Source: "..\..\..\Scheduler\bin\Release\DevExpress.XtraScheduler.v19.1.dll"; DestDir: "{app}" ; Flags: ignoreversion      
    Source: "..\..\..\Scheduler\bin\Release\DevExpress.XtraScheduler.v19.1.Core.dll"; DestDir: "{app}" ; Flags: ignoreversion      
    Source: "..\..\..\Scheduler\bin\Release\DevExpress.XtraScheduler.v19.1.Extensions.dll"; DestDir: "{app}" ; Flags: ignoreversion      
    Source: "..\..\..\SpreadSheet\bin\Release\DevExpress.XtraSpreadsheet.v19.1.dll"; DestDir: "{app}" ; Flags: ignoreversion
    Source: "..\..\..\SpreadSheet\bin\Release\DevExpress.DataAccess.v19.1.UI.dll"; DestDir: "{app}" ; Flags: ignoreversion

    [Icons]
    Name: "{userdesktop}\AutoTRAX"; Filename: "{app}\AutoTRAX.exe"; Tasks: desktopicon
    Name: "{userdesktop}\Spreadsheet"; Filename: "{app}\Spreadsheet.exe"; Tasks: desktopicon
    Name: "{userdesktop}\Scheduler"; Filename: "{app}\Scheduler.exe"; Tasks: desktopicon
    Name: "{userdesktop}\Text Editor"; Filename: "{app}\TextEditor.exe"; Tasks: desktopicon
    Name: "{userdesktop}\Active3D"; Filename: "{app}\Active3D.exe"; Tasks: desktopicon
    Name: "{userdesktop}\Sketcher"; Filename: "{app}\Sketcher.exe"; Tasks: desktopicon
    Name: "{userdesktop}\Part Creator"; Filename: "{app}\PartCreator.exe"; Tasks: desktopicon

    Name: "{group}\DEX\Uninstall AutoTRAX Design Express"; Filename: "{uninstallexe}"
    Name: "{group}\DEX\AutoTRAX DEX"; Filename: "{app}\AutoTRAX.exe"; WorkingDir: "{app}"
    Name: "{group}\DEX\AutoTRAX DEX Help"; Filename: "{app}\DEX.chm"; WorkingDir: "{app}"
    Name: "{group}\DEX\AutoTRAX Spreadsheet"; Filename: "{app}\SpreadSheet.exe"; WorkingDir: "{app}"
    Name: "{group}\DEX\AutoTRAX Scheduler"; Filename: "{app}\Scheduler.exe"; WorkingDir: "{app}"
    Name: "{group}\DEX\AutoTRAX Text Editor"; Filename: "{app}\TextEditor.exe"; WorkingDir: "{app}"
    Name: "{group}\DEX\AutoTRAX Active3D"; Filename: "{app}\Active3D.exe"; WorkingDir: "{app}"
    Name: "{group}\DEX\AutoTRAX Sketcher"; Filename: "{app}\Sketcher.exe"; WorkingDir: "{app}"
    Name: "{group}\DEX\AutoTRAX Part Creator"; Filename: "{app}\PartCreator.exe"; WorkingDir: "{app}"

    [Run]
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\AutoTRAX.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing AutoTRAX performance for your system. This may take some time ...;
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\Simulator.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing Simulator performance for your system. This may take some time ...;
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\SpreadSheet.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing Spreadsheet performance for your system. This may take some time ...;
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\Scheduler.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing Scheduler performance for your system. This may take some time ...;
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\TextEditor.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing the Text Editor performance for your system. This may take some time ...;
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\Active3D.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing Active3D's performance for your system. This may take some time ...;
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\Sketcher.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing Sketcher's performance for your system. This may take some time ...;
    Filename: {dotnet40}\ngen.exe; Parameters: "install ""{app}\PartCreator.exe"" /nologo"; WorkingDir: {app}; Flags: runhidden; StatusMsg: Optimizing Part Creator's performance for your system. This may take some time ...;
    Filename: "{app}\AutoTRAX.exe"; Parameters: "/noUpdateCheck"; WorkingDir: "{app}"; StatusMsg: "Running AutoTRAX..."; Flags: hidewizard nowait

    [code]


    function InitializeSetup(): Boolean;
    begin
    Result := true;
    end;


     function Framework45IsNotInstalled(): Boolean;
    var
      bSuccess: Boolean;
      regVersion: Cardinal;
    begin
      Result := True;

      bSuccess := RegQueryDWordValue(HKLM, 'Software\Microsoft\NET Framework Setup\NDP\v4\Full', 'Release', regVersion);
      if (True = bSuccess) and (regVersion >= 378389) then begin
        Result := False;
      end;
    end;

    procedure InitializeWizard;
    begin
      if Framework45IsNotInstalled() then
      begin
        idpAddFile('http://go.microsoft.com/fwlink/?LinkId=397707', ExpandConstant('{tmp}\NetFrameworkInstaller.exe'));
        idpDownloadAfter(wpReady);
      end;
    end;


    procedure InstallFramework;
    var
      StatusText: string;
      ResultCode: Integer;
    begin
      StatusText := WizardForm.StatusLabel.Caption;
      WizardForm.StatusLabel.Caption := 'Installing .NET Framework 4.5.2. This might take a few minutes...';
      WizardForm.ProgressGauge.Style := npbstMarquee;
      try
        if not Exec(ExpandConstant('{tmp}\NetFrameworkInstaller.exe'), '/passive /norestart', '', SW_SHOW, ewWaitUntilTerminated, ResultCode) then
        begin
          MsgBox('.NET installation failed with code: ' + IntToStr(ResultCode) + '.', mbError, MB_OK);
        end;
      finally
        WizardForm.StatusLabel.Caption := StatusText;
        WizardForm.ProgressGauge.Style := npbstNormal;

        DeleteFile(ExpandConstant('{tmp}\NetFrameworkInstaller.exe'));
      end;
    end;

    procedure CurStepChanged(CurStep: TSetupStep);
    begin
      case CurStep of
        ssPostInstall:
          begin
            if Framework45IsNotInstalled() then
            begin
              InstallFramework();
            end;
          end;
      end;
    end;
    The developer of AutoTRAX DEX. 
    ·
  • The installer does not install the library.


    The developer of AutoTRAX DEX. 
    ·
  • I will still be very careful with may library. It might be deleted of other reasons than installing or uninstalling DEX. Most probably my own mistakes.

    As always, back-up important things!
    ·
  • Remember that if you actually have deleted your library you can remake it by exporting the parts from your project files!
    ·
  • Bengt

    A very good tip

    Thanks
    ·
Sign In or Register to comment.